1 CLEAR168:SCREEN4:COLOR0,1,2:CLS:PRINT"CITADELLE":LOCATE0,2:PRINT"3-le Sceptre d'Irun":LOCATE18,3:PRINT"1984-LORICIELS":TS=TIME
2 LOCATE5,7:PRINT"PRESSEZ LA TOUCHE LOCK":LOCATE10,8:PRINT"PUIS ESPACE":LOCATE0,14:PRINT"Adaptation Sanyo PHC-25";:LOCATE15,15:PRINT"2012 David BOURG";:GOSUB561
3 SCREEN2:COLOR2,0,1:AC=10:DO=5:PV=100:SO=5:PC=1:NB=2:ST=2:KEY1,"OUVRE":KEY2,"PRENDS":KEY3,"REGARDE":KEY4,"FOUILLE":GOSUB540:P=1:GOSUB43:GOTO17
4 PRINTA$;:RETURN
5 COLOR1,0,0:PRINTA$:RETURN
6 COLOR5,0,0
7 PRINTA$:RETURN
8 GOTO7:REM CITADELLE-3 12778 1493 134
9 GOSUB560
17 CONSOLE9,15:CLS
18 COLOR3,0,0:A$="Que faites-vous ":GOSUB4:INPUTC$
19 IFC$="O"THENC$="OUE"
20 IFC$="E"THENC$="EST"
21 IFC$="N"THENC$="NOR"
22 IFC$="S"THENC$="SUD"
23 LO=LEN(C$):IFLO<3THEN17
24 COLOR0,0,0:PRINT:MI=0:FORA=1TOLO
25 B$=MID$(C$,A,1):IFB$=" "THENMI=A
26 NEXTA:IFMI=0THENX$=C$:M=0:MI=4:GOTO31
27 W$=RIGHT$(C$,LO-MI):Y$=LEFT$(W$,3):IFY$="SAN"ORY$="CHA"ORY$="HAL"ORY$="ENT"ORY$="LAB"ORY$="COU"ORY$="DON"THENY$="SAL"
28 IFY$="FEM"THENY$="SQU"
29 M=0:FORA=1TO33:IFY$=M$(A)THENM=A
30 NEXTA:IFM=0THENA$=U$:GOSUB6:PRINTW$;".":GOTO9
31 X$=LEFT$(C$,MI-1):Z$=LEFT$(X$,3)
32 V=0:FORA=1TO29:IFZ$=V$(A)THENV=A
33 NEXTA:IFV=0THENA$=U$:GOSUB6:PRINTX$;".":GOTO9
35 IFV<10THEN41
36 IFV=17ANDM=26THEN348
37 IF(V=23ORV=24)ANDM=20THEN404
38 IF(V=25ORV=26)ANDM=20THEN408
39 IFV=3ANDM=21ANDP=1THEN308
40 ONPGOTO70,80,90,100,110,120,130,140,150,160,170,180,190,573,220,220,220,220,220,573,270
41 ONVGOTO480,487,494,500,482,482,482,482,475
42 PC=P:P=T(P,V-4):IFP=0THEN566
43 CONSOLE0,15:CLS:COLOR1,2,0:CONSOLE1,15:LOCATE19,0:COLOR1,0,0:PRINT"L I E U :"+STR$(P)
45 COLOR5,0,0:A$=S$+"dans "
55 ONPGOSUB506,507,511,512,513,514,515,516,517,521,522,523,524,525,526,527,527,527,527,528,529
56 PRINT:COLOR0,0,1:A$="Objets :":GOSUB4
57 FORB=20TO34:IFP(B-19)=PTHENA$=N$(B-19)+" ":GOSUB4
58 NEXTB
59 PRINT:COLOR2,0,0:A$="Issues :":GOSUB4:IFT(P,1)>0THENA$=" Nord":GOSUB4
60 IFT(P,2)>0THENA$=" Sud":GOSUB4
61 IFT(P,3)>0THENA$=" Est":GOSUB4
62 IFT(P,4)>0THENA$=" Ouest":GOSUB4
63 IFQ(1)<>PANDQ(2)<>PANDQ(3)<>PANDQ(4)<>PANDQ(5)<>PANDQ(7)<>PANDQ(8)<>PANDQ(9)<>PTHENMO=0:RETURN
64 PRINT:MO=0:COLOR3,0,0:A$="Monstres :":GOSUB4
65 FORA=1TO9:IFQ(A)=PTHENA$=Q$(A)+" ":GOSUB4:MO=A
66 NEXTA:PRINT:RETURN
70 IFV=1ANDM=1THEN300
71 IFV=10ANDM=1THEN301
72 IFV=10ANDM=21THEN303
73 IFV=1ANDM=21THEN304
74 IF(V=21ORV=24)ANDM=20THEN305
75 IFV=19ANDM=21THEN306
79 GOTO573
80 IFV=11ANDM=2THEN310
81 IFV=12ANDM=3THEN324
82 IF(V=1ORV=10)ANDM=14THEN312
83 IF(V=14ORV=24)ANDM=21ANDP(2)=0THEN315
84 IFV=1ANDM=3THEN318
85 IFV=10ANDM=3THEN320
89 GOTO573
90 IFV=12ANDM=3THEN322
99 GOTO573
100 IFV=11ANDM=2THEN328
101 IFV=10ANDM=5THEN330
102 IF(V=14ORV=24)ANDM=6THEN332
109 GOTO573
110 IFV=10ANDM=7THEN334
111 IFV=11ANDM=7THEN336
112 IFV=22ANDM=8THEN340
113 IFV=1ANDM=9THEN342
114 IF(V=16ANDM=2)OR((V>24ANDV<29)AND(M=4ORM=9))THEN344
119 GOTO573
120 IFV=22ANDM=10THEN346
122 IFV=18ANDM=8THEN350
123 IFV=11ANDM=11THEN352
124 IFV=11ANDM=2THEN354
129 GOTO573
130 IFV=1ANDM=12THEN356
131 IFV=1ANDM=13THEN365
139 GOTO573
140 IFV=22ANDM=10THEN357
149 GOTO573
150 IFV=19ANDM=13THEN360
151 IFV=11ANDM=2THEN362
152 IF(V=1ORV=10)ANDM=13THEN364
159 GOTO573
160 IFV=1ANDM=14THEN366
161 IFV=20ANDM=15THEN368
162 IFV=10ANDM=15THEN370
169 GOTO573
170 IF(V=21ORV=27ORV=28)ANDM=18THEN372
171 IFV=13ANDM=30THEN374
172 IFV=11ANDM=2THEN376
173 IF(V=1ORV=10)ANDM=14THEN378
179 GOTO573
180 IFV=22ANDM=10THEN382
181 IFV=22ANDM=16THEN384
189 GOTO573
190 IFV=11ANDM=2THEN380
191 IF(V=1ORV=10)ANDM=9THEN386
192 IFV=1ANDM=17THEN388
193 IF(V=15ORV=27)ANDM=29THEN390
199 GOTO573
220 IFV=10ANDM=14THEN312
221 IF(V=22ORV=1)ANDM=14THEN382
222 IF(V=22ORV=1)ANDM=16ANDP=15THEN394
229 GOTO573
270 IF(V=22ORV=1)ANDM=19THEN396
279 GOTO573
300 A$="Ce sont de farouches guerriers. L'un d'eux tient un sceptre.":GOSUB5:GOTO9
301 A$="Au dessous est ecrit:'le sceptred'IRUN deviendra or; alors KRORH":GOSUB4:A$="reviendra des tenebres.'":GOSUB5:GOTO9
302 IFSC=1THENA$="Il est en or.":GOSUB5:GOTO9
303 A$="Il est fait d'un metal bleute etdegage une forte chaleur.":GOSUB5:GOTO9
304 A$="Sa tete represente un crocodile.":GOSUB5:GOTO9
305 IFSC=1THEN572
306 IFP(1)<>0ORGAN=0THENA$="Impossible, c'est brulant!":GOSUB5:GOTO9
308 A$="Le sceptre luit a l'approche du gantelet.  A son contact, il se transforme en or.":GOSUB5:P(2)=1:SC=1:GOTO9
310 IFPV<60THEN565
311 T(2,4)=3:A$="Elle grince de facon lugubre.":GOSUB591:GOTO9
312 A$="Il est fait de dalles de granit.":GOSUB5
313 IFDAL=1ANDP<15THENA$="Une des dalles est descellee.":GOSUB5
314 GOTO9
315 IFDAL=0THEN568
316 A$="Le sceptre s'enfonce & disparaitdans un bruit sourd.":GOSUB5:A$="Un passage s'ouvre a l'est!":GOSUB591:T(2,3)=15:SC=0:P(2)=-1:NB=NB-1:GOTO9
318 A$="Elles forment des motifs        geometriques.":GOSUB5:GOTO9
320 A$="L'une d'elles  a  une  couleur  differente.":GOSUB5:GOTO9
322 IFP(4)<>0THEN568
323 A$="Aucune dalle ne bouge.":GOSUB5:GOTO9
324 IFP(4)<>0THEN568
325 IFDAL=1THEN571
326 DAL=1:A$="Vous descellez la dalle. "+R$+"dessous un emplacement pour un  sceptre.":GOSUB5:GOTO9
328 IFBO=1THENA$=T$:GOSUB5:GOTO9
329 A$="La porte resiste puis cede":GOSUB591:T(4,4)=5:GOTO9
330 A$="Elles font dix pieds de haut et l'une d'elles a la marque d'une main.":GOSUB5:GOTO9
332 A$="Un passage s'ouvre au nord.":T(4,1)=10:GOSUB591:GOTO9
334 A$="Sur un cote,"+R$+"le trou d'une serrure.":GOSUB5:GOTO9
336 IFP(5)<>0THEN568
337 IFP(6)<>-5THEN567
338 A$=R$+N$(6)+".":GOSUB590:P(6)=5:GOTO9
340 IFP(5)<>-5THEN571
341 A$="Une clef tombe sur le sol.":GOSUB590:P(5)=5:GOTO9
342 IFBO=1THEN567
343 A$="Sur l'une d'elles est posee une poutre pour bloquer la porte au sud.":GOSUB5:GOTO9
344 IFBO=1THEN571
345 A$="Vous bloquez la porte a l'est & ouvrez la porte au sud.":GOSUB591::T(5,3)=0:T(4,4)=0:T(5,2)=6::BO=1:GOTO9
346 IFP(7)<>-6THEN567
347 A$=R$+N$(7)+".":P(7)=6:GOSUB590:GOTO9
348 IFP(7)<>0THEN570
349 A$="A la vue d'une croix, disparait le spectre.":GOSUB5:GOTO9
350 IFP(8)<>-6THEN567
351 A$="Un diamant tombe de l'un d'eux.":P(8)=6:GOSUB590:GOTO9
352 A$="Une tete de demon coupee s'animeet dit: Seul le cercle...  Elle se liquefie en sang.":GOSUB5:GOTO9
354 T(6,3)=7:A$="La porte s'ouvre sans resister.":GOSUB591:GOTO9
356 A$="Derriere, une salle de garde.":GOSUB5:GOTO9
357 IFP(9)<>-8THEN567
358 A$=R$+"une fleche d'argent et unarc.":P(9)=8:P(10)=8:GOSUB590:GOTO9
360 IFST<1THEN572
361 A$="La statue prend vie.":ST=ST-1:PM=50:AM=5:DM=15:GOSUB5:GOSUB420:GOSUB43:GOTO484
362 A$=T$:GOSUB5:GOTO9
364 IFST<1THEN568
365 A$="Elles representent des demons":GOSUB5:GOTO9
366 A$="Au centre de la piece, "+R$:GOSUB5:A$="un pentacle. Y git une femme nue":GOSUB5:GOTO9
368 A$="Trois eclairs me repoussent.":GOSUB5:PV=PV-20:GOTO9
370 A$="Vous lisez: la mort frappe l'infidele.":GOSUB5:GOTO9
372 A$="Un spectre surgit & hurle:  QUI OSE TROUBLER MON REPOS ?":GOSUB5:GOTO9
374 IFP(11)<>0THEN570
375 A$="Le spectre disparait en hurlant,laissant sur le sol son gantelet":P(1)=11:GOSUB5:GOTO9
376 A$="Vous sentez une aura magique.":GOSUB5:T(11,4)=9:GOTO9
378 A$="Des traces menent au socle":GOSUB5:GOTO9
380 A$="Vous ouvrez la porte.":T(13,4)=12:T(12,3)=13:GOSUB591:GOTO9
382 A$=R$+"un squelette.":GOSUB5:GOTO9
384 IFP(11)<>-12THEN567
385 A$="Sur sa poitrine,  vous  trouvez une croix de bois.":P(11)=12:GOSUB590:GOTO9
386 A$="Un fier archer y est represente":GOSUB5:GOTO9
388 A$="C'est un puits sans fin. Au loinvous distinguez une cible.":GOSUB5:GOTO9
390 IFP(10)<>0THEN570
391 A$="Elle se dirige tout droit  vers la cible.":GOSUB5:A$="Une passerelle suspendue descendjusqu'a vous.":GOSUB5
392 T(13,3)=14:P(10)=-16:GOTO9
394 A$="Sur le mur derriere lui, "+R$+"une inscription: la NONNE trouvetoujours son chemin.":GOSUB5:GOTO9
396 A$="Vous regardez vers le donjon.   Une creature geante mi-homme mi-bete se jette vers vous.":GOSUB5
397 GOSUB560:CLS:A$="La bete vous defie et dit"
398 IFP(14)<>0ANDP(15)<>0THENPV=1
399 GOSUB420:CONSOLE0,15:CLS
400 A$="VOUS AVEZ VAINCU KRORH":GOSUB5:A$=S$+"le nouveau maitre de  la CITADELLE !":GOSUB5:PRINT:A$="VOUS AVEZ GAGNE":GOSUB5
401 GOSUB560:GOTO423
404 IFP(1)<>0THEN570
405 IFGAN=1THEN571
406 A$="Vous enfilez le gantelet;    Il protege parfaitement votre main":GAN=1:GOSUB5:GOTO9
408 IFP(1)<>0THEN570
409 IFGAN=0THENA$="Vous ne le portez pas.":GOSUB5:GOTO9
410 A$="Vous retirez le gant.":GAN=0:GOSUB5:GOTO9
420 PM=RND(1)*40+10:AM=RND(1)*15:DM=RND(1)*15:IFP=21THENPM=300
421 GOSUB560:CONSOLE0,15:CLS:COLOR3,0,1:CONSOLE5,15:LOCATE10,0:PRINT "C O M B A T":COLOR2,0,1
422 LOCATE11,1:A$="<A>TTAQUE":GOSUB7:LOCATE11,2:A$="<D>EFENSE":GOSUB7:LOCATE11,3:A$="<S>ORTILEGE":GOSUB7:LOCATE11,4:A$="<F>UITE":GOSUB7
423 PLAY"V10L64O2AGR64AR64O3L8CR64L64O2AGR64AR64O3L4D#","V10L64O3EDR64ER64L8GR64L64EDR64ER64L4O3A#"
425 GOSUB560:CLS:LOCATE5,5:A$="Que faites-vous ":GOSUB4:INPUTA$
426 IFA$="A"THEN431
427 IFA$="D"THEN432
428 IFA$="S"THEN454
429 IFA$="F"THEN461
430 LOCATE0,5:GOTO425
431 A1=2:A2=4:A3=-14:GOTO433
432 A1=0:A2=0:A3=0
433 TC=INT(RND(1)*20+1):IF(18-TC)<AMTHEN439
434 A$="Vous l'avez rate.":GOSUB7:IFAM<5THENA$="Il est tres resistant.":GOSUB7
435 TC=INT(RND(1)*20+1):IF(20-TC)<AC-A2THEN444
436 A$="Le monstre m'a rate.":GOSUB7
437 IFA3<>0THEN449
438 GOTO430
439 A$="Vous l'avez touche.":GOSUB7:D=INT(RND(1)*DO-A2-A3+1)
440 IFD>8THENA$="C'est un coup de maitre.":GOSUB7
441 PM=PM-D:IFPM<0THENA$="Le monstre tombe mort.":GOSUB7:GOTO451
442 B=RND(1):IFB<.5THENA$="Vous avez l'avantage.":GOSUB7:PRINT:GOTO433
443 GOTO435
444 A$=S$+"touche.":GOSUB7:D=INT(RND(1)*DM+1)
445 IFD>8THENA$="Attention, il est tres fort.":GOSUB7
446 PV=PV-D:IFPV<0THEN462
447 B=RND(1):IFB<.5THENA$="Attention, il a l'avantage.":GOSUB7:GOTO435
448 GOTO430
449 B=RND(1):IFB<.5THEN439
450 GOTO430
451 IFPM<-3THENA$="et disparait.":GOSUB7:Q(MO)=0:GOTO453
452 Q(MO)=INT(RND(1)*13+1)
453 PR=PR+1:PLAY "T140L8V10O3BF+BO4C+D+O3BO4D+F+T90A+FD+CD2","T140L8V7O3BF+BO4C+D+O3BO4D+F+T90A+FD+CD2","T140V10O1L1BA+L2A+":GOSUB560:RETURN
454 IFSO=0THENA$="Vous n'avez plus aucun sort.":GOSUB7:GOTO435
455 SO=SO-1
456 A$="Vous lancez un sort.":GOSUB7:B=RND(1)
457 IFB<.25THENA$="Le monstre contre le sort.":GOSUB7:PRINT:GOTO435
458 D=8:A$="Le sort atteind le monstre.":GOSUB7:PM=PM-D
459 IFPM<0THENA$="et le foudroie.":GOSUB7:PRINT:PR=PR+1:Q(MO)=0:GOSUB560:RETURN
460 GOTO430
461 P=PC:GOSUB43:GOTO9
462 CONSOLE0,15:CLS
463 A$="Une voix retentit:":GOSUB7
464 A$="JE SUIS KRORH, LE SEUL MAITRE DELA CITADELLE.":GOSUB7:PRINT
465 A$="VOS RESTES NE SERONT QUE LA     MARQUE DE MON POUVOIR.":GOSUB7:PRINT:A$="VOUS AVEZ PERDU !":GOSUB7
466 PLAY"T100V10L16O3FCO2G#O3CO2G#FL3D","T100V8L16O2FCO1G#O2CO1G#FL3D":LOCATE0,11:A$="Voulez-vous rejouer ":GOSUB4:INPUTA$:IFLEFT$(A$,1)="O"THENRUN
467 CLS:END
475 CONSOLE 9,15:CLS:O=0:X=0:PRINT"Vous possedez "
476 FORB=20TO34:IFP(B-19)=0THENA$=N$(B-19)+" ":GOSUB4:O=O+1
477 NEXTB
478 IFO=0THENA$="Mon courage pour seul bien.":X=0:LOCATE0,11:GOSUB530
479 GOTO9
480 IFM<>0THENGOTO40
481 GOSUB43:GOTO9
482 GOSUB42
484 IFMO<>0THENGOSUB420:GOSUB43:GOTO484
485 GOTO9
487 LOCATE 0,9:A$="EXPERIENCE :          ":GOSUB4:PRINTPR*100
488 A$="VIE :                 ":GOSUB4:PRINTPV
489 A$="ATTAQUE :             ":GOSUB4:PRINTDO
490 A$="DEFENSE :             ":GOSUB4:PRINTAC
491 A$="NOMBRE DE SORTS :     ":GOSUB4:PRINTSO:TI=INT((TIME-TS)/21600)
492 A$="TEMPS DE JEU : "+STR$(INT((TIME-TS)/21600))+" minutes":GOSUB4
493 GOTO9
494 IFNB=8ORM<20THEN569
495 IFP(M-19)<>PTHEN568
496 P(M-19)=0:NB=NB+1
497 IFM=31THENDO=15
498 IFM=32THENAC=AC-5
499 A$="Vous prenez l'objet.":GOSUB5:GOTO9
500 IFNB=0ORM<20THEN570
501 IFP(M-19)<>0THEN568
502 P(M-19)=P:NB=NB-1
503 IFM=31THENDO=5
504 IFM=32THENAC=AC+5
505 A$="Vous posez l'objet sur le sol.":GOSUB5:GOTO9
506 A$=A$+" une  salle  de  transfert. Il y a des sculpturessur les murs.":GOSUB8:RETURN
507 A$=A$+L$+".":GOSUB8:A$="A l'ouest, une porte de metal.":GOSUB8
508 IFDAL=1THENA$=R$+"un trou dans le dallage.":GOSUB8
509 RETURN
511 A$=A$+"un grand hall. Lesol est dalle.  A l'est, il y a une porte de metal.":GOSUB8:RETURN
512 A$=A$+L$+" avec, de chaque cote, des colonnes    alignees & une porte a l'ouest.":GOSUB8:RETURN
513 A$=A$+"la salle du troneIl y a le trone, des tables, un siege et au sud, une porte.":GOSUB8:RETURN
514 A$=A$+" la chambre  du  seigneur.   Il y a une armoire, un lit, un siege, une table et al'est, une porte.":GOSUB8:RETURN
515 A$=A$+L$+". "+R$+"2 statues. A l'est, une grille":GOSUB8:RETURN
516 A$=A$+"la salle de gardeIl y a une table, deux lits, et deux sieges.":GOSUB8:RETURN
517 A$=A$+L$+".":GOSUB8:A$=R$+"2 colonnes":IFST<1THENGOSUB8
518 IFST=1THENA$=A$+", une statue.":GOSUB8
519 IFST=2THENA$=A$+", deux statues":GOSUB8
520 A$="A l'est, une porte.":GOSUB8:RETURN
521 A$=A$+"une chambre vide.":GOSUB8::RETURN
522 A$=A$+"un sanctuaire. Aucentre,  vous voyez un socle de pierre et a l'ouest, une porte.":GOSUB8:A$="":GOSUB8:RETURN
523 A$=A$+"une chambre. Il ya un lit, deux sieges et a l'est une porte.":GOSUB8:RETURN
524 A$=A$+L$+".":GOSUB8:A$="A l'ouest, il y a un tableau et une porte. Un passage est perce dans le mur est.":GOSUB8:RETURN
525 A$=S$+"sur une passerelle. Ily a un passage au sud. Sur  le  mur nord, une sculpture.":GOSUB8:RETURN
526 A$=S$+"devant l'entree  d'un labyrinthe.":GOSUB8:RETURN
527 A$=A$+"un labyrinthe.":GOSUB8:RETURN
528 A$=S$+"sorti du labyrinthe.":GOSUB8:RETURN
529 A$=A$+" une  vaste cour fermee que surplombe un donjon.":GOSUB8:RETURN
530 LOCATEX,11:COLOR7,0,0:GOSUB7:RETURN
540 U$="Je ne comprends pas :":T$="Vous n'y arrivez pas.":S$="Vous etes ":R$="Il y a ":L$="un couloir"
541 DATA 2,,,,,1,,,9,8,2,4,,7,3,,,,4,,5,,,,4,,,,3,,,,13,3,,,,4,,,,,,,,,,,,9,,,,11,,13,16,15,15,15,15,15,15,17,18,15,15,15,19,15,15,15,15,15,20,15,,,21,,,,,
542 DIMT(21,4):FORA=1TO21:FORB=1TO4:READT(A,B):NEXTB,A
543 DATA REG,SCO,PRE,POS,NOR,SUD,EST,OUE,INV,EXA,OUV,DES,MON,PLA,DEC,BLO,LIS,EVE,TOU,ENT,DEP,FOU,ENF,MET,RET,ENL,TIR,POU,FOR
544 DIMV$(29):FORA=1TO29:READV$(A):NEXTA
545 DATA SCU,POR,DAL,POU,COL,MAI,TRO,SIE,TAB,LIT,ARM,GRI,STA,SOL,PEN,SQU,MUR,SOC,SAL
546 DIMM$(34):FORA=1TO19:READM$(A):NEXTA
547 DATA GAN,un gantelet,-11,SCE,un sceptre,-2,POI,un poignard,12,BAR,une barre,3,CLE,une cle,-5,EME,une emeraude,-5
548 DATA PAR,un parchemin,-6,DIA,un diamant,-6,ARC,un arc,-8,FLE,une fleche d'argent,-8,CRO,une croix,-12
549 DATA MAS,une masse,1,CUI,une cuirasse,1,BOU,le bouclier d'Oran,0,ESP,l'espadon de Kranz,0
550 DIMN$(15),P(15):FORA=20TO34:READM$(A),N$(A-19),P(A-19):NEXTA
551 DATA un assassin,2,un magicien,4,une lich,6,un orc,8,une harpie,9,un guerrier,12,un squelette,14,un gnoll,11,une ombre,11
552 DIMQ$(9),Q(9):FORA=1TO9:READQ$(A),Q(A):NEXTA
553 RETURN
560 C$="":LOCATE10,15:COLOR1,0,0:A$="Pressez une touche...":GOSUB4
561 K$=INKEY$:IFK$=""THEN561
562 RETURN
565 A$=S$+"trop faible.":GOSUB6:GOTO9
566 A$="Il n'y a pas d'issue de ce cote.":GOSUB6:P=PC:RETURN
567 A$="Il n'y a rien de special.":GOSUB6:GOTO9
568 A$="Vous ne pouvez pas faire cela.":GOSUB6:GOTO9
569 A$=S$+"trop charge.":GOSUB6:GOTO9
570 A$="Vous ne l'avez pas.":GOSUB6:GOTO9
571 A$="Vous l'avez deja fait.":GOSUB6:GOTO9
572 A$="Il ne se passe rien.":GOSUB6:GOTO9
573 IFV=1ORV=10ORV=22THEN567
580 GOTO568
590 GOSUB5:PLAY"T100V10L64O5CO6CO7CV8CV6GV4C","T100V10L64O4CO5CO6CGD#CV8CV6GV4C":RETURN
591 GOSUB5:PLAY"V10L8O2FF#GL4G#","V10L8O3CC#DL4D#":RETURN
